UDF TEXTJOIN, Fungsi TEXTJOIN untuk Excel 2007 - 2016

Daftar Isi

Rumus Excel [.] com - Fungsi TEXTJOIN adalah salah satu fungsi baru di Excel 2019, fungsi ini dapat digunakan untuk menggabungkan data dari beberapa sel / range dengan pembatas tertentu, selengkapnya untuk cara penggunaannya, bisa Anda baca di artikel cara menggunakan Fungsi TEXTJOIN.

Karena baru ditambahkan mulai Excel 2019, maka untuk pengguna excel yang masih menggunakan versi dibawahnya, seperti Excel 2016, Excel 2013, Excel 2010 dan Excel 2007 otomatis tidak dapat menggunakan Fungsi TEXTJOIN ini karena memang belum tersedia.

Jika ingin di Excel 2016 ke bawah ada fungsi TEXTJOIN maka salah satu caranya adalah membuat sendiri fungsi tersebut dengan VBA atau istilahnya User Defined Function (UDF). 

Namun saran saya baiknya sih upgrade Excelnya ke versi terbaru, jadi gak perlu repot bikin UDF seperti ini 😃

Contoh hasil dari UDF TEXTJOIN di Excel 2007

Sengaja untuk praktek bikin UDF-nya menggunakan Excel 2007, kalau di Excel 2007 berhasil, tentu di versi yang lebih baru (Excel 2010, Excel 2013 dan Excel 2016) pasti juga akan berhasil,

Cara Membuat UDF TEXTJOIN

Untuk membuat UDF (user defined function) TEXTJOIN dengan VBA Excel caranya adalah sebagai berikut:

1. Buka aplikasi Microsoft Visual Basic, bisa melalui Tab Developer - Visual Basic, atau bisa juga menggunakan shortcut Alt + F11.
2. Tambahkan Module baru pada VBA Project, dengan cara klik menu Insert - Module.
   
   
   
   
   
3. Pada Module masukkan script vba berikut:
   
   

   
   Option Explicit
   
   Function TEXTJOIN( Delimiter As String, _
       Ignore_empty As Boolean, _
       ParamArray Text() As Variant) As String
   Dim x, i As Long, pemisah As String, teks As String
   For i = LBound(Text) To UBound(Text)
       If IsArray(Text(i)) Then
           For Each x In Text(i)
               teks = IIf(IsMissing(x), "", x)
               If Not (Ignore_empty And teks = "") Then
                   TEXTJOIN = TEXTJOIN & pemisah & teks
                   pemisah = Delimiter
               End If
           Next x
       Else
           teks = IIf(IsMissing(Text(i)), "", Text(i))
           If Not (Ignore_empty And teks = "") Then
               TEXTJOIN = TEXTJOIN & pemisah & teks
               pemisah = Delimiter
           End If
       End If
   Next i
   End Function
   

   
   
   Jika Anda memasukkan kode VBA ini di Excel 2019, Excel 2021 atau di Excel 365 maka Anda harus mengubah Nama UDF-nya, agar tidak bentrok dengan fungsi TEXTJOIN yang sudah ada di Excel 2019, Excel 2021 dan Excel 365, misalnya di ubah namanya menjadi JOINTEXT atau GABUNGTEKS dsb.
4. Sekarang harusnya UDF TEXTJOIN sudah bisa digunakan, bisa di coba mengetikkan =te harusnya fungsi TEXTJOIN-nya akan ditampilkan.
   
   
   
   
   

Sintaksis UDF TEXTJOIN

Untuk penulisan sintaksis UDF TEXTJOIN sama dengan Fungsi TEXTJOIN.

=TEXTJOIN (delimiter; ignore_empty; text1, [text2], …)

Keterangan:

• delimiter : pemisah antar teks yang digabungkan.
• ignore_empty : pilihan mengabaikan sel kosong, bisa di isi 1 atau TRUE dan 0 atau FALSE.
• text1, text2 dst : teks, sel atau range yang isinya ingin digabungkan.

Contoh pertama penggunaan UDF TEXTJOIN:

=TEXTJOIN(" ";TRUE;A1:B1)

hasilnya:

Contoh kedua UDF TEXTJOIN:

=TEXTJOIN(" ";TRUE;A2:B3)

hasilnya:

Setelah Fungsi TEXTJOIN berhasil digunakan, Anda bisa menyimpan file Excel-nya dalam bentuk *.xls. *.xlsm atau *.xlsb agar kode VBA-nya bisa ikut tersimpan dan tidak hilang. Anda juga bisa menyimpannya dalam format *.xlam jika ingin menjadikan Fungsi TEXTJOIN ini sebagai Add-in Excel.

Sekian tutorial tentang cara membuat UDF TEXTJOIN di Excel, Semoga Bermanfaat.